I thought I'd share my old autologin that I have reworked and now only uses LavishScript. it saves time starting more than one session without having to type in account names and passwords
Create a file named AL.ISS and place it in the InnerSpace\Scripts folder.
The syntax and parameters are in the code.
Code: Select all
/* -----------------------------------------------------------------------------------
* AL.iss - LavishScript AutoLogin for EverQuest II
* Created: By hegvape
*
* 1.0 (150731) - Remake of EQ2AutoLogin. Works with standard EQ2 UI.
*
* Todo:
- Make sure Caps Lock is turned off...
* -----------------------------------------------------------------------------------
* Description:
* Send password to the login screen and press Enter
* Syntax: run AL <Password> [Wait]
*/
function main(string PwdVar, string DlyVar)
{
variable int CntMsClks=1
variable string MyAppl=AutoLogin
/* Check if password has been supplied when starting the script */
if !${PwdVar.Length}
{
/* Optionally You can specify Your password below */
PwdVar:Set[-?]
}
;switch ${PwdVar}
{
case ?
case /?
case -?
echo " "
echo "Syntax: run AL <Password> [Wait]"
echo " "
echo " Where <Password> specifies your account password (required)."
echo " Where [Wait] specifies the pause in 10th/sec before executing (optional)."
echo " "
echo " Use InnerSpace Configuration to create a specific game profile for your account."
echo " Add AL.iss to the startup sequence of your profile. Ex: RUN AL your_Password"
echo " "
echo " To automate the login further then add the parameters, described below, to the 'Main executable parameters' section of your game profile."
echo " "
echo " Parameters for EverQuest2.exe: cl_username <Your_Account_Name>;cl_autoplay_char <Character_Name>;cl_autoplay_world <World_Server>"
echo " Note! Character names are case sensitive and You need to separate the parameters with a semicolon ';'."
echo " "
return
case Default
}
echo "--------------------------"
echo ${MyAppl}: Script Started!
/* Execute delay if provided */
if ${DlyVar.Length}
{
echo ${MyAppl}: Waiting for ${Math.Calc[${DlyVar}/10].Precision[1]} sec...
wait ${DlyVar}
}
/* Do mouse clicks to speed up the login (SOE Logo, ESRB Rating, Advertisement, EQ2 Title) */
CntMsClks:Set[1]
do
{
echo ${MyAppl}: Executing mouse click ${CntMsClks}
MouseClick -hold left
waitframe
wait .5
MouseClick -release left
waitframe
wait .5
}
while ${CntMsClks:Inc}<=4
echo ${MyAppl}: Using LavishScript... Make sure CAPS LOCK is Off!
; press -hold "Caps Lock" ;This Doesn't work
type ${PwdVar}
squelch press Enter ;US, DK Keyb
squelch press Retur ;SE Keyb
/* Load extensions */
call Load_Extension
echo "-----------------------"
echo ${MyAppl}: Script Done!
Script:End
}
function Load_Extension()
{
/* Try to load Extension_Name if not already loaded - Replace Extension_Name with your actual extension */
if !${Extension[Extension_Name](exists)}
{
echo ${MyAppl}": Loading extension Extension_Name..."
ext Extension_Name
}
}